Elasticity/Kinematics example 4

Example 4

Given:

Displacement field $𝐮=\kappa X_2{\widehat{𝐞}}_1+\kappa X_1{\widehat{𝐞}}_2$.

Find:

1. The Lagrangian Green strain tensor $𝑬$.
2. The infinitesimal strain tensor $\mathit{\epsilon }$.
3. The infintesimal rotation tensor $\mathit{\omega }$.
4. The infinitesimal rotation vector $\mathit{\theta }$.
5. The exact longitudinal strain in the reference material direction ${𝐞}_1$.
6. The approximate longitudinal strain in the direction ${𝐞}_1$ based on the infinitesimal strain tensor $\mathit{\epsilon }$.

Solution

The Maple output of the computations are shown below:

  with(linalg): with(LinearAlgebra): 
  X := array(1..3): x := array(1..3):
  e1 := array(1..3,[1,0,0]): 
  e2 := array(1..3,[0,1,0]): 
  e3 := array(1..3,[0,0,1]):
  u := evalm(k*X[2]*e1 + k*X[1]*e2);

$u:=[k{X}_2,k{X}_1,0]$

  x := evalm(u + X);

$x:=[k{X}_2+X_1,k{X}_1+X_2,X_3]$

  F := linalg[matrix](3,3):
  for i from 1 to 3 do
    for j from 1 to 3 do
      F[i,j] := diff(x[i],X[j]);
    end do;
  end do;
  evalm(F);

$F:=\left[\begin{array}{ccc}1& k& 0\\ k& 1& 0\\ 0& 0& 1\end{array}\right]$

  Id := IdentityMatrix(3): C := evalm(transpose(F)&*F); 
  E := evalm((1/2)*(C - Id));

$C:=\left[\begin{array}{ccc}1+k^2& 2k& 0\\ 2k& 1+k^2& 0\\ 0& 0& 1\end{array}\right]$

$E:=\left[\begin{array}{ccc}\frac{k^2}{2}& k& 0\\ [2ex]k& \frac{k^2}{2}& 0\\ [2ex]0& 0& 0\end{array}\right]$

  gradu := linalg[matrix](3,3):
  for i from 1 to 3 do
    for j from 1 to 3 do
      gradu[i,j] := diff(u[i],X[j]);
    end do;
  end do;
  evalm(gradu);

$gradu:=\left[\begin{array}{ccc}0& k& 0\\ k& 0& 0\\ 0& 0& 0\end{array}\right]$

  epsilon := evalm((1/2)*(gradu + transpose(gradu)));

$\epsilon :=\left[\begin{array}{ccc}0& k& 0\\ k& 0& 0\\ 0& 0& 0\end{array}\right]$

  omega := evalm((1/2)*(gradu - transpose(gradu)));

$\omega :=\left[\begin{array}{ccc}0& 0& 0\\ 0& 0& 0\\ 0& 0& 0\end{array}\right]$

  stretch1 :=  sqrt(evalm(evalm(e1&*C)&*transpose(e1))[1,1]):
  longStrain1 := stretch1 - 1;

$𝑠𝑡𝑟𝑒𝑡𝑐ℎ1:=\sqrt{1+k^2}$

$𝑙𝑜𝑛𝑔𝑆𝑡𝑟𝑎𝑖𝑛1:=\sqrt{1+k^2}-1$

  approxLongStrain1 := evalm(evalm(e1&*epsilon)&*transpose(e1))[1,1];

$𝑎𝑝𝑝𝑟𝑜𝑥𝐿𝑜𝑛𝑔𝑆𝑡𝑟𝑎𝑖𝑛1:=0$

The geometrical difference between the large strain and small strain cases can be observed by looking at the figures from the previous examples.